Mettre en place un gestionnaire de rafraîchissement automatique des tables

Je tiens à remercier tout particulièrement toutes celles et tous ceux qui ont participé à la relecture de ce document en y incluant leurs remarques.

Pour tout renseignement complémentaire, veuillez me contacter directement (Argyronet) par MP.

La mise en œuvre de cet automatisme est toute simple et ne requiert que très peu de code.

Il se présente par la mise en place d'un Module de classe du fait que l'on a besoin de l'instancier pour autant de tables que nécessaire.
Chaque table à surveiller n'est en fait pas vraiment une table, mais un formulaire en mode Feuille de données qui est le reflet exact de la table à surveiller.

En effet, il n'est pas possible de déclencher des événements sur un objet de type Table.

Il sera certainement nécessaire de masquer certaines colonnes superflues pour l'examen des données qu'elles doivent recevoir.

Comme vous pouvez le voir ci-dessus, la table/formulaire affichée possède un titre représentant son nom (celui de la table source qui est le nom d'objet affecté par défaut) et juxtaposé, le temps restant avant le prochain rafraîchissement.

Rappel sur la méthode Requery

C'est effectivement cette méthode qui est employée pour rafraîchir les enregistrements de la table.

La méthode Requery met à jour les données sous-jacentes d'un formulaire ou d'un contrôle de manière à tenir compte des nouveaux enregistrements de la source d'enregistrements ou des enregistrements supprimés depuis la dernière interrogation.

§ Extrait de l'aide de Microsoft Access- La méthode Requery exécute à nouveau la requête à partir de laquelle le formulaire ou le contrôle a été créé.
- Elle affiche tous les enregistrements nouveaux ou modifiés ou retire les enregistrements supprimés de la table à partir de laquelle le formulaire ou le contrôle a été créé.
- Elle met à jour les enregistrements affichés en fonction des changements apportés à la propriété Filter du formulaire.

expression.Requery(NomContrôle)

Quelques exemples.

Docmd.Requery
'ou
MyComboBox.Requery
'ou
Me.Requery

Ce formulaire initialise des propriétés au chargement (Load) puis exploite son événement Timer pour rafraîchir les données qu'il contient.

Un intervalle de 16 secondes est défini par défaut pour que la méthode Requery soit appelée de nouveau.
La routine déclenchée par l'événement Timer exploite une variable statique pour effectuer ce décompte.

Étape N° 1

Vous avez plusieurs solutions pour créer le formulaire.

Pour les chevronnés, créez donc un formulaire en mode Feuille de données, provoquez-lui le code événementiel par défaut et passez directement à l'étape N° 2.

Pour les autres, sélectionnez la table concernée et usez donc de l'Assistant formulaire.

Pour créer le premier formulaire, sélectionnez alors la table depuis la fenêtre Base de données.

Cliquez alors sur la barre d'outils « Base de données » et dérouler le menu-bouton Nouvel objet : Formulaire automatique.

Choisissez alors la rubrique Formulaire comme indiqué ci-dessous.

Dès que la fenêtre de l'assistant s'affiche, cliquez sur Formulaire instantané : feuille de données et cliquez sur OK ou bien double-cliquez sur cette rubrique.

Un très bref instant suffit à afficher le formulaire dans le mode souhaité.

Enregistrez-le donc sous son nom par défaut, à savoir, celui de la table source puis passez immédiatement en Mode création.

Depuis la barre d'outils « Création de formulaires », cliquez sur le bouton « Code » en sélectionnant « Procédure événementielle » si toutefois vous n'avez pas défini cette option par défaut dans les options d'Access.

L'éditeur Visual Basic fait alors son apparition avec une feuille vierge.
(Ou du moins, pourvue de l'option Option Compare Database et peut-être Option Explicit si vous avez coché l'option idoine dans les préférences de l'éditeur VBE.)

Étape N° 2

Dans l'interface VBE et depuis le menu Insertion, ajoutez un Module de classe.

puis nommez-le « clsAutoRefresh ».

Dans la nouvelle feuille de ce module, vous allez ajouter :
- 2 propriétés publiques ;
- 3 procédures Sub(), publiques également.

Les deux propriétés sont dédiées à définir pour l'une le titre de la fenêtre du formulaire en récupérant sa propriété Caption et l'autre de type Integer déterminera le déclenchement du Timer par une valeur comprise entre 0 (Disabled) et 1000 (1 seconde et Enabled).

Vous définirez ces propriétés en Lecture/Écriture et les nommerez respectivement :
- p_strFormCaption ;
- p_intTimerInterval.

Les trois procédures publiques à ajouter seront nommées :
- FormDblClick ;
- FormOnLoad ;
- FormOnTimer.

Comme vous pouvez sans doute le remarquer, les noms de ces procédures ne vous sont pas inconnus.
Ils portent en effet le nom respectif de chaque événement en regard dans le formulaire à savoir, respectivement :
Form_DblClick(), Form_Load() et Form_Timer().

Les propriétés exploitent deux variables privées locales portant un nom identique hormis le préfixe « m » qui détermine leur appartenance à un module comme le veulent les conventions typographiques du code VB.

III-B-1. La procédure FormDblClick▲

III-B-2. La procédure FormOnLoad▲

III-B-3. La procédure FormOnTimer▲

Cette procédure calcule le temps restant par rapport au paramètre ResetTime défini par défaut à 16 secondes.

Vous pouvez bien entendu définir la valeur de votre choix ici.

La variable statique S s'incrémente de 1 à chaque appel de cet événement soit pendant seize secondes puis recommence.

La variable locale D se décrémente de la différence restant entre la valeur de ResetTime et celle de S ce qui permet en outre d'alimenter le titre de la fenêtre du formulaire dynamiquement avec ce temps restant.

Pendant la décrémentation de la valeur de la variable statique S, la propriété Caption se voit affectée de sa valeur d'origine, à savoir le nom du formulaire défini lors du chargement (Form_Load), concaténée au temps restant ou au message du rafraîchissement imminent selon le cas.

La méthode Requery est alors appelée et les données sont rafraîchies aussitôt.

III-B-4. Le code du module de classe▲

Option Compare Database
Option Explicit

'**********************************************************************
' Module            : clsAutoRefresh
' Type              : Module de classe
' DateTime          : 10/10/2009
' Author            : Jean-Philippe AMBROSINO
' Purpose           : Classe dédiée au rafraîchissement automatique des données
'**********************************************************************
Option Compare Database
Option Explicit

Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)

Private m_intTimerInterval                             As Integer
Private m_strFormCaption                              As String

' Propriété de valeur du Timer
Public Property Get p_intTimerInterval() As Integer
    p_intTimerInterval = m_intTimerInterval
End Property

Public Property Let p_intTimerInterval(ByVal ip_intTimerInterval As Integer)
    m_intTimerInterval = ip_intTimerInterval
End Property

' Propriété de la légende du formulaire
Public Property Get p_strFormCaption() As String
    p_strFormCaption = m_strFormCaption
End Property

Public Property Let p_strFormCaption(ByVal sp_strFormCaption As String)
    m_strFormCaption = sp_strFormCaption
End Property

' Événement DoubleClick du formulaire (Zone grisée)
Public Sub FormDblClick(ByRef TargetForm As Form, Cancel As Integer)
    If p_intTimerInterval Then
        p_intTimerInterval = 0
        TargetForm.Caption = p_strFormCaption & " (Rafraîchissement stoppé : Pressez un double-clic pour le relancer...)"
    Else
        p_intTimerInterval = 1000
    End If
    TargetForm.TimerInterval = p_intTimerInterval
End Sub

' Événement Load du formulaire
Public Sub FormOnLoad(ByRef TargetForm As Form)
    p_strFormCaption = TargetForm.Caption
    TargetForm.TimerInterval = 1000
End Sub

' Événement Timer du formulaire
Public Sub FormOnTimer(ByRef TargetForm As Form, Optional ByVal ResetTime As Integer = 16)
Dim D                                                  As Integer
Static S                                               As Integer

    If S = ResetTime Then
        S = 0: D = 0
        TargetForm.Caption = "Rafraîchissement imminent...."
        Sleep 1000
        DoEvents
        TargetForm.Requery
    End If

    S = S + 1
    D = ResetTime - S
    DoEvents
    TargetForm.Caption = p_strFormCaption & " : Rafraîchissement des données dans " & D & " seconde" & IIf(D <= 1, "", "s")
End Sub

III-B-5. Mise en place du code pour le formulaire▲

Une fois cela fait, vous allez maintenant enrichir le module de classe du formulaire concerné.

Normalement et si vous avez bien suivi le déroulement de ce tutoriel, vous devez pouvoir accéder à cette classe depuis VBE.

Ici, vous allez donc gérer les événements correspondants comme expliqués ci-après.

Comme vu ci-avant, vous allez appliquer le code de l'objet Form pour chacun des événements Load(), DblClick() et Timer().

Le code de chacun des événements est très simple puisqu'il suffit d'appliquer la procédure du même nom avec les paramètres idoines à partir de la variable objet mc_AutoRefresh :

'**********************************************************************
' Module            : TBL_ExcelFileData (DataSheetForm)
' Type              : Document VBA
' DateTime          : 09/10/2009
' Author            : Jean-Philippe AMBROSINO
' Purpose           : Formulaire contenant les importations temporaires Excel
'**********************************************************************
Option Compare Database
Option Explicit

Private mc_AutoRefresh As clsAutoRefresh

Private Sub Form_Close()
    Set mc_AutoRefresh = Nothing
End Sub

Private Sub Form_DblClick(Cancel As Integer)
    mc_AutoRefresh.FormDblClick Me, Cancel
End Sub

Private Sub Form_Load()
    Set mc_AutoRefresh = New clsAutoRefresh
    With mc_AutoRefresh
        .p_strFormCaption = Me.Caption
        .p_intTimerInterval = 1000
        Me.TimerInterval = .p_intTimerInterval
    End With
End Sub

Private Sub Form_Timer()
    mc_AutoRefresh.FormOnTimer Me
End Sub

Dans l'en-tête du module, vous déclarez une variable objet qui va servir à instancier la classe précédemment créée. Vous nommez cette variable mc_AutoRefresh.
C'est l'événement Load() qui va attribuer la référence à cette variable par le biais de l'instruction Set et du mot clé New qui lui, va créer une nouvelle instance de la classe.

La variable de module se voit mettre sa valeur à néant par le biais de Nothing lors de la fermeture du formulaire.

Pour appliquer le même effet de rafraîchissement à d'autres formulaires, créez les autres formulaires avec le même mode, à savoir « Feuille de données ».
Recopiez alors le code de la classe du précédent formulaire dans celle de chacun des autres formulaires.

Enregistrez le tout et par acquit de conscience, cliquez sur le menu Debogage puis sur la rubrique Compiler <Votre projet> afin de vous assurer que vous n'avez rien omis.

C'est terminé ; vous pouvez appuyer sur la touche F5 depuis la fenêtre principale d'Access afin d'ouvrir chaque formulaire.
Cliquez ensuite sur le menu Fenêtre puis sur Mosaïque horizontale pour les ranger.